"HELP THE HENOKO AND DUGONG"
Please stop the government! Our dugong are crying !! And we are crying!!!
US government and Japanese government has a plan of the construction of the HUGE MILITURY BASE at Okinawa now. Please stop them! That plan will destroy not only the living environment of dugong, but also OUR LIVING ENVIRONMENT in Okinawa.
Will you kill us, and our dugong? Please appeal to the public and your government to stop that plan. Please help us!!!!

2008年10月31日

Oracle 10g XE

 SJISで構築することが必要な時があります。サンプル .cmd を公開します。


:Oracle 10g XE のDBをutf-8ではなく、sjisで作り直すバッチ

:Oracle 10g XE インストールフォルダー、新規インスタンス名、sysの初期設定パスワードの指定
set orapath=C:\oraclexe\
set instance=新規インスタンス名
set password=systemのパスワード

:リスナー停止
lsnrctl stop LISTENER

:規定instance停止
oradim -SHUTDOWN -SID XE -SHUTTYPE SRVC,INST -SHUTMODE ABORT
:作成済みinstance停止
oradim -SHUTDOWN -SID %instance% -SHUTTYPE SRVC,INST -SHUTMODE ABORT

:作成instance削除
oradim -DELETE -SID %instance%

:ファイル削除
del /S /F /Q %orapath%app\oracle\product\10.2.0\server\dbs\*
del /F /Q %orapath%app\oracle\product\10.2.0\server\database\*.log
del /F /Q %orapath%app\oracle\product\10.2.0\server\database\*.dat
del /F /Q %orapath%app\oracle\product\10.2.0\server\database\*.ora
del /F /Q %orapath%app\oracle\product\10.2.0\server\database\*.sql
del /F /Q %orapath%oradata\XE\*

:instanceフォルダの再生成
rmdir /S /Q %orapath%oradata\%instance%
mkdir %orapath%oradata\%instance%
rmdir /S /Q %orapath%app\oracle\admin\%instance%\
mkdir %orapath%app\oracle\admin\%instance%\
mkdir %orapath%app\oracle\admin\%instance%\adump
mkdir %orapath%app\oracle\admin\%instance%\bdump
mkdir %orapath%app\oracle\admin\%instance%\cdump
mkdir %orapath%app\oracle\admin\%instance%\dpdump
mkdir %orapath%app\oracle\admin\%instance%\pfile
mkdir %orapath%app\oracle\admin\%instance%\udump

:pfile作成
set pfile=%orapath%app\oracle\product\10.2.0\server\database\init%instance%.ora

echo java_pool_size=0 > %pfile%
echo large_pool_size=4194304 >> %pfile%
echo shared_pool_size=62914560 >> %pfile%
echo streams_pool_size=0 >> %pfile%
echo audit_file_dest='%orapath%app\oracle\admin\%instance%\adump' >> %pfile%
echo background_dump_dest='%orapath%app\oracle\admin\%instance%\bdump' >> %pfile%
echo compatible='10.2.0.1.0' >> %pfile%
echo control_files='%orapath%oradata\%instance%\control.dbf' >> %pfile%
echo core_dump_dest='%orapath%app\oracle\admin\%instance%\cdump' >> %pfile%
echo db_name='%instance%' >> %pfile%
echo dispatchers='(PROTOCOL=TCP) (SERVICE=XEXDB)' >> %pfile%
echo job_queue_processes=2 >> %pfile%
echo open_cursors=300 >> %pfile%
echo os_authent_prefix='' >> %pfile%
echo pga_aggregate_target=40M >> %pfile%
echo remote_login_passwordfile='EXCLUSIVE' >> %pfile%
echo sessions=20 >> %pfile%
echo sga_target=140M >> %pfile%
echo shared_servers=1 >> %pfile%
echo undo_management='AUTO' >> %pfile%
echo undo_tablespace='UNDO' >> %pfile%
echo user_dump_dest='%orapath%app\oracle\admin\%instance%\udump' >> %pfile%

:サービス作成
oradim -NEW -SID %instance% -SYSPWD %password% -PFILE %pfile% -STARTMODE auto

:setup.sql作成
set sqlfile=%orapath%app\oracle\product\10.2.0\server\database\setup.sql

echo spool %orapath%app\oracle\product\10.2.0\server\database\CreateDB.log > %sqlfile%

::spfile作成
:echo create spfile='%spfile%' from pfile='%pfile%'; >> %sqlfile%

:instance起動
echo startup nomount; >> %sqlfile%

::DB構築
echo create database %instance% >> %sqlfile%
echo logfile group 1 ('%orapath%oradata\%instance%\redo1.dbf') size 32M, >> %sqlfile%
echo group 2 ('%orapath%oradata\%instance%\redo2.dbf') size 32M, >> %sqlfile%
echo group 3 ('%orapath%oradata\%instance%\redo3.dbf') size 32M >> %sqlfile%
echo character set JA16SJISTILDE >> %sqlfile%
echo national character set utf8 >> %sqlfile%
echo datafile '%orapath%oradata\%instance%\system.dbf' >> %sqlfile%
echo size 240M >> %sqlfile%
echo autoextend on >> %sqlfile%
echo next 16M maxsize unlimited >> %sqlfile%
echo extent management local >> %sqlfile%
echo sysaux datafile '%orapath%oradata\%instance%\sysaux.dbf' >> %sqlfile%
echo size 48M >> %sqlfile%
echo autoextend on >> %sqlfile%
echo next 8M >> %sqlfile%
echo maxsize unlimited >> %sqlfile%
echo undo tablespace undo >> %sqlfile%
echo datafile '%orapath%oradata\%instance%\undo.dbf' >> %sqlfile%
echo size 48M >> %sqlfile%
echo autoextend on >> %sqlfile%
echo default temporary tablespace temp >> %sqlfile%
echo tempfile '%orapath%oradata\%instance%\temp.dbf' >> %sqlfile%
echo size 8M >> %sqlfile%
echo autoextend on; >> %sqlfile%

::table表領域作成
echo create tablespace users >> %sqlfile%
echo datafile '%orapath%oradata\%instance%\users.dbf' >> %sqlfile%
echo size 210M reuse >> %sqlfile%
echo autoextend on >> %sqlfile%
echo extent management local >> %sqlfile%
echo autoallocate >> %sqlfile%
echo segment space management auto; >> %sqlfile%

::index表領域作成
echo create tablespace idx_users >> %sqlfile%
echo datafile '%orapath%oradata\%instance%\index.dbf' >> %sqlfile%
echo size 210M reuse >> %sqlfile%
echo autoextend on >> %sqlfile%
echo extent management local >> %sqlfile%
echo autoallocate >> %sqlfile%
echo segment space management auto; >> %sqlfile%

:カタログ作成(エラーが出るけど無視していい様子)
echo @%orapath%app\oracle\product\10.2.0\server\RDBMS\ADMIN\catalog.sql >> %sqlfile%
echo @%orapath%app\oracle\product\10.2.0\server\RDBMS\ADMIN\catproc.sql >> %sqlfile%

:ユーザプロファイルの作成
echo connect system/manager >> %sqlfile%
echo @%orapath%app\oracle\product\10.2.0\server\sqlplus\admin\pupbld.sql >> %sqlfile%
echo spool off >> %sqlfile%
echo quit >> %sqlfile%

:setup.sql実行
set ORACLE_SID=%instance%
sqlplus / "as sysdba" @%sqlfile%

:パスワードファイルの再作成
orapwd file=orapw%instance% password=%password%

:tnsnames.oraの作成

set tnsfile=%orapath%app\oracle\product\10.2.0\server\NETWORK\ADMIN\tnsnames.ora

if /i exist "%tnsfile%.%instance%.org" goto skipmktns

copy %tnsfile% %tnsfile%.%instance%.org
echo. >> %tnsfile%
echo %instance% = >> %tnsfile%
echo (DESCRIPTION = >> %tnsfile%
echo (ADDRESS_LIST = >> %tnsfile%
echo (ADDRESS = (PROTOCOL = TCP)(HOST = 172.0.0.1)(PORT = 1521)) >> %tnsfile%
echo ) >> %tnsfile%
echo (CONNECT_DATA = >> %tnsfile%
echo (SERVER = DEDICATED) >> %tnsfile%
echo (SERVICE_NAME = %instance%) >> %tnsfile%
echo ) >> %tnsfile%
echo ) >> %tnsfile%
echo. >> %tnsfile%

:skipmktns

:サービスの構成
sc config OracleServiceXE start= demand
sc config OracleService%instance% start= auto

:リスナー開始
lsnrctl start LISTENER

:機動モード設定など

:oradim -EDIT -SID %instance% -SYSPWD %password% -STARTMODE auto
:oradim -SHUTDOWN -SID %instance% -SYSPWD %password% -SHUTTYPE SRVC,INST -SHUTMODE ABORT
:oradim -STARTUP -SID %instance% -SYSPWD %password%

echo 終了です。


posted by Jitoh at 19:07 | 沖縄 ☀ | Comment(0) | TrackBack(0) | 開発 | このブログの読者になる | 更新情報をチェックする
この記事へのコメント
コメントを書く
お名前: [必須入力]

メールアドレス:

ホームページアドレス:

コメント: [必須入力]

認証コード: [必須入力]
CAPTCHA

※画像の中の文字を半角で入力してください。
※ブログオーナーが承認したコメントのみ表示されます。

この記事へのトラックバック
×

この広告は180日以上新しい記事の投稿がないブログに表示されております。